***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Mar 12, 2021                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt SM8S14A-AU A K 
.param
+vc0 = 4.106e-10	vc1 = 4.256e-10		vc2 = 1.000		vc3 = 6.485e-11		vc4 = 4.582e-1
+tc1 = 5.621e-2		tc2 = 2.641e-2		tc3 = 1.801e-2		tc4 = 2.721e-2
.func irexp(v) {(vc0+vc1*v^vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irexp(v(K,A))}
.model zener d
***** flag parameter *****
+level = 1 
***** dc model parameter *****
+ is = 1.197e-12	   n = 1.060		  rs = 2.098e-3
+ibv = 5.0e-3		 nbv = 1.0		  bv = 16.4
+ikf = 816.7e-0
***** capacitance parameter *****
+cjo = 2.199e-8		   m = 3.370e-1		  vj = 5.495e-1 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.091		 xti = 3
+trs1 = -7.025e-4	trs2 = 1.105e-5		tikf = 1.0e-3
+tbv1 = 7.324e-4	tbv2 = -2.203e-7	
.ends SM8S14A-AU
*$
